《VBA数据库解决方案》教程（版权10090845）是我推出的第二套教程，目前已经是第二版修订了。这套教程定位于中级，是学完字典后的另一个专题讲解。数据库是数据处理的利器，教程中详细介绍了利用ADO连接ACCDB和EXCEL的方法和实例操作，教程第一版的修订内容主要是完成所有程序文件的32位和64位OFFICE系统测试。
这套教程共两册，八十四讲，今后一段时间会给大家陆续推出修订后的教程内容。今日的内容是：VBA数据库解决方案第二十八讲 删除数据表数据，然后导入工作表中数据
【分享成果，随喜正能量】一个社会，不同意见是正常的，不要急于去反对，或者扣帽子，甚至去打压与自己不同见解的人，对于不同意见最好的处理方式，就是辩论，只有辩论，才会出真知。
第二十八讲 删除数据表数据，然后导入工作表中数据
大家好,我们今日继续讲解VBA数据库解决方案的第28讲内容：利用VBA，把数据表中对应工作表的数据首先删除,然后向数据表中导入工作表数据。数据库的讲解已经持续一段时间了，从对简单数据库的认识到利用VBA对数据库的操作，我们一步步的走来，估计大家已经学到了很多知识。最近的内容主要是操作，我把可能的各种情况给大家介绍讲解，这些都是我们在实际的工作中会遇到的情况，只要大家掌握了代码，并结合一下自己的工作实际，很快就会写出自己的代码。当然要想改代码必须对代码有全面的理解。
1 应用场景的具体分析
今日给大家讲的情况是：数据库录入错了，但关键的字段没有错误，这时我们怎么处理呢？这时的处理方案是：首先要删除之前录入的数据，然后修改数据并再次录入。
实例：我们在录入员工信息时，不小心把民族给录入错误，如下面的工作表：
人员的民族应该为汉，不小心录入了数字，这时改怎么处理呢？这就是我这节要面对的解决方案：先删除，再导入正确的。
2 在数据表中先删除已有的数据，然后添加记录的代码及代码解读
怎么做到呢，看下面的代码：
Sub mynz_28() '第28讲 利用VBA,根据工作表的数据，在数据表中先删除已有的数据，然后添加记录
Dim cnADO As Object, rsADO As Object
Dim strPath As String, strTable As String, strWhere As String, strSQL As String, strMsg As String
Set cnADO = CreateObject("ADODB.Connection")
Set rsADO = CreateObject("ADODB.Recordset")
strPath = ThisWorkbook.Path & "\mydata2.accdb"
strTable = "员工信息"
cnADO.Open "Provider=Microsoft.Ace.OLEDB.12.0;Data Source=" & strPath
'汇报给用户记录数
strSQL = "SELECT * FROM " & strTable
rsADO.Open strSQL, cnADO, 1, 3
MsgBox "当前记录数为：" & rsADO.RecordCount
rsADO.Close
'打开数据表中存在的员工编号相同的记录
strSQL = "DELETE FROM " & strTable & " A WHERE EXISTS(" _
& "SELECT * FROM [Excel 12.0;Database=" & _
ThisWorkbook.FullName & "].[" & ActiveSheet.Name & "$" _
& Range("a1").CurrentRegion.Address(0, 0) & "] " _
& "WHERE 员工编号=A.员工编号)"
cnADO.Execute strSQL '把这些记录删除
'下面将添加记录
strSQL = "INSERT INTO " & strTable & " SELECT * FROM [Excel 12.0;Database=" _
& ThisWorkbook.FullName & ";].[" & ActiveSheet.Name & "$" _
& Range("A1").CurrentRegion.Address(0, 0) & "]"
cnADO.Execute strSQL
MsgBox "纪录添加成功。", vbInformation, "添加纪录"
'汇报给用户记录数
strSQL = "SELECT * FROM " & strTable
rsADO.Open strSQL, cnADO, 1, 3
MsgBox "最后的记录数为：" & rsADO.RecordCount
'释放内存
rsADO.Close
cnADO.Close
Set rsADO = Nothing
Set cnADO = Nothing
End Sub
代码截图：
代码解读，代码共分三部分：
1) 第一部分仍是建立连接记录集一直到MsgBox "当前记录数为：" & rsADO.RecordCount 后关闭了记录集的连接，这部分和前几讲的内容是一致的，不再过多的讲解，
2) 第二部分：
'打开数据表中存在的员工编号相同的记录
strSQL = "DELETE FROM " & strTable & " A WHERE EXISTS(" _
& "SELECT * FROM [Excel 12.0;Database=" & _
ThisWorkbook.FullName & "].[" & ActiveSheet.Name & "$" _
& Range("a1").CurrentRegion.Address(0, 0) & "] " _
& "WHERE 员工编号=A.员工编号)"
cnADO.Execute strSQL '把这些记录删除
'下面将添加记录
strSQL = "INSERT INTO " & strTable & " SELECT * FROM [Excel 12.0;Database=" _
& ThisWorkbook.FullName & ";].[" & ActiveSheet.Name & "$" _
& Range("A1").CurrentRegion.Address(0, 0) & "]"
cnADO.Execute strSQL
MsgBox "纪录添加成功。", vbInformation, "添加纪录"
这部分中，先要打开已经有的记录，然后删除，接着，在此导入正确的记录。我们要理解的是：strSQL = "DELETE FROM " & strTable & " A WHERE EXISTS(" _
& "SELECT * FROM [Excel 12.0;Database=" & _
ThisWorkbook.FullName & "].[" & ActiveSheet.Name & "$" _
& Range("a1").CurrentRegion.Address(0, 0) & "] " _
& "WHERE 员工编号=A.员工编号)"
这条SQL语句的意思是删除一些记录，什么记录呢？就是在数据表strTable中两者员工编号相同的记录。然后，ADO 执行SQL命令：cnADO.Execute strSQL 。
在此导入记录就相对简单了：同样
strSQL = "INSERT INTO " & strTable & " SELECT * FROM [Excel 12.0;Database=" _
& ThisWorkbook.FullName & ";].[" & ActiveSheet.Name & "$" _
& Range("A1").CurrentRegion.Address(0, 0) & "]"
然后执行。
这里我们介绍一下Execute命令和INSERT INTO 命令的意义：
Execute 方法可以执行指定SQL 语句.
INSERT INTO 语句用于向表格中插入新的行。
3) 第三部分的代码是从汇报给用户记录数，同时要释放内存。这部分就不再多说了。
下面看看我们程序的运行情况：
我们首先修正EXCEL工作表中的记录为正确的值：
然后运行，首先会提示当前的记录数：
然后,后台删除记录，添加记录，提示给我们：
最后反馈处理完成的记录：
我们这时可以再看看数据库中的记录,点击总记录显示：
可以看到我们修改完成。
今日内容回向：
1 如何修改已经存在的记录？
2 除了上述方案，完成本讲的内容，你是否还有其他的方案？
本讲内容参考程序文件：VBA与数据库操作（第一册）.xlsm
我20多年的VBA实践经验，全部浓缩在下面的各个教程中：
